<%
' **********************************************************
' データ読出し
' **********************************************************
Function GetData( )

	Query = "select 商品マスタ.*,商品分類マスタ.商品分類 as 商品分類2,名称"
	Query = Query & " from 商品マスタ,商品分類マスタ"
	Query = Query & " where 商品マスタ.商品分類 = 商品分類マスタ.商品分類"
	Query = Query & " and 商品コード = " & Ss(MyData("In1Key"))

	if DBGet( Cn, Rs, Query, false ) then
		Call EditQueryData(  )
	end if

End Function

' **********************************************************
' データベースデータの編集
' **********************************************************
Function EditQueryData(  )

	MyData("In2Name")	= Rs.Fields("商品名").Value & ""
	MyData("In2Fname")	= Rs.Fields("フリガナ").Value & ""
	MyData("In2Ztanka")	= Rs.Fields("在庫評価単価").Value & ""
	MyData("In2Htanka")	= Rs.Fields("販売単価").Value & ""
	MyData("In2Sbun")	= Rs.Fields("商品分類").Value & ""
	MyData("In2Skubun")	= Rs.Fields("商品区分").Value & ""
	MyData("In2SbunName") = Rs.Fields("名称").Value & ""

End Function

' **********************************************************
' VIEW の編集
' **********************************************************
Function EditDataHead( )


End Function

' **********************************************************
' VIEW2 の編集
' **********************************************************
Function EditDataBody( )

	Query = "select コード, 名称 from コード名称マスタ"
	Query = Query & " where 区分 = 4 order by コード"
	OptionList = CreateOption( Cn, Rs, "In2Skubun", Query )

End Function

' **********************************************************
' データベースへの更新
' **********************************************************
Function UpdateData(  )

	Query = "select * from 商品マスタ"
	Query = Query & " where 商品コード = " & Ss(MyData("In1Key"))

	if DBGet( Cn, Rs, Query, false ) then

		Query = "update 商品マスタ"
		Query = Query & " set "
		Query = Query & "商品名 = " & Ss(MyData("In2Name"))
		Query = Query & ",フリガナ = " & Ss(MyData("In2Fname"))
		Query = Query & ",在庫評価単価 = " & MyData("In2Ztanka")
		Query = Query & ",販売単価 = " & MyData("In2Htanka")
		Query = Query & ",商品分類 = " & Ss(MyData("In2Sbun"))
		Query = Query & ",商品区分 = " & Ss(MyData("In2Skubun"))
		Query = Query & ",更新日 = CURDATE() "
		Query = Query & " where 商品コード = " & Ss(MyData("In1Key"))

		on error resume next		
		Cn.Execute( Query )
		if Err.Number <> 0 then
			ErrMessage = "更新に失敗しました<br>" & vbCrLf & Err.Description
		end if
		on error goto 0

	else

		Query = "insert into 商品マスタ"
		Query = Query & " (商品コード,商品名,フリガナ"
		Query = Query & ",在庫評価単価,販売単価,商品分類"
		Query = Query & ",商品区分,作成日,更新日) "
		Query = Query & " values("
		Query = Query & Ss(MyData("In1Key"))
		Query = Query & "," & Ss(MyData("In2Name"))
		Query = Query & "," & Ss(MyData("In2Fname"))
		Query = Query & "," & MyData("In2Ztanka")
		Query = Query & "," & MyData("In2Htanka")
		Query = Query & "," & Ss(MyData("In2Sbun"))
		Query = Query & "," & Ss(MyData("In2Skubun"))
		Query = Query & ",CURDATE(),CURDATE()"
		Query = Query & ")"
		
		on error resume next		
		Cn.Execute( Query )
		if Err.Number <> 0 then
			ErrMessage = "登録に失敗しました<br>" & vbCrLf & Err.Description
		end if
		on error goto 0

	end if

End Function

' **********************************************************
' 行の削除
' **********************************************************
Function DeleteData(  )

	Query = "delete from 商品マスタ"
	Query = Query & " where 商品コード = " & Ss(MyData("In1Key"))

	on error resume next		
	Cn.Execute( Query )
	if Err.Number <> 0 then
		ErrMessage = "削除に失敗しました<br>" & vbCrLf & Err.Description
	end if
	on error goto 0

End Function

' **********************************************************
' エラーチェック
' **********************************************************
Function CheckDataHead( )

	if  Trim( MyData("In1Key") ) = "" then
		ErrMessage = "商品コードは必須入力です"
	end if

End Function

' **********************************************************
' エラーチェック
' **********************************************************
Function CheckDataBody( )
	
	if Trim( MyData("In2Name") ) = "" then
		ErrMessage = "名称は必須入力です"
	end if

End Function
%>