Const adLockReadOnly = 1
Const adLockOptimistic = 3

' ******************************************************
' DB接続(MDB)
' ******************************************************
Function MDB_DBConnect( _
    Connection, _
    File _
)

    Dim ConnectionString

    ConnectionString = _
        "Provider=Microsoft.Jet.OLEDB.4.0;" & _
        "Data Source=" & File & ";"

    Connection.Open ConnectionString

End Function

' ******************************************************
' DB読込み
' 【戻り値】: True(データ有り),False(データ無し)
' ******************************************************
Function DBGet( _
    Connection, _
    Record, _
    SqlQuery, _
    bUpadateFlg _
)
    
    ' 閉じていない時は閉じる
    If Record.State >= 1 Then
        Record.Close
    End If
    
    ' 更新処理に使用する場合は、レコード単位の共有的ロック
    If bUpadateFlg Then
        Record.LockType = adLockOptimistic
    Else
        Record.LockType = adLockReadOnly
    End If
    
    ' レコードセット作成
    Record.Open SqlQuery, Connection
    If Record.EOF Then
        DBGet = False
    Else
        DBGet = True
    End If

End Function

' ******************************************************
' DB終了処理(接続を閉じる)
' ******************************************************
Function DBClose( _
    CnRs _
)
    
    On Error Resume Next
    If CnRs.State >= 1 Then
        CnRs.Close
    End If

    DBClose = True

End Function