データベース接続


  Oracle : VBScript ( OO4O + DatabasePool )



  
' **********************************************************
' オブジェクト作成
' **********************************************************
Set OraSession = CreateObject( "OracleInProcServer.XOraSession" )
Set Fs = CreateObject( "Scripting.FileSystemObject" )

' **********************************************************
' 接続
' **********************************************************
on error resume next
OraSession.CreateDatabasePool 1,40,200,"lightbox", "lightbox/lightbox", 0
if Err.Number <> 0 then
	Wscript.Echo OraSession.LastServerErrText
	Wscript.Quit
end if
on error goto 0
Set OraDatabase	= OraSession.GetDatabaseFromPool(10)
OraDatabase.LastServerErrReset

' **********************************************************
' レコードセット取得
' **********************************************************
Query = "select * from 社員マスタ"
on error resume next
Set OraDynaset = OraDatabase.CreateDynaset(Query,2)
if Err.Number <> 0 then
	Wscript.Echo OraDatabase.LastServerErrText
	Wscript.Quit
end if
on error goto 0

' **********************************************************
' 出力ファイルオープン
' **********************************************************
Set Csv = Fs.CreateTextFile( "社員マスタ.csv", True )

' **********************************************************
' タイトル出力
' **********************************************************
Buffer = ""
For i = 0 to OraDynaset.Fields.Count - 1
	if Buffer <> "" then
		Buffer = Buffer & ","
	end if
	Buffer = Buffer & OraDynaset.Fields(i).Name
Next
Csv.WriteLine Buffer

' **********************************************************
' データ出力
' **********************************************************
Do While not OraDynaset.EOF
	Buffer = ""
	For i = 0 to OraDynaset.Fields.Count - 1
		if Buffer <> "" then
			Buffer = Buffer & ","
		end if
		Buffer = Buffer & OraDynaset.Fields(i).Value
	Next
	Csv.WriteLine Buffer
	OraDynaset.MoveNext
Loop

' **********************************************************
' ファイルクローズ
' **********************************************************
Csv.Close

' **********************************************************
' オブジェクト解放
' **********************************************************
Set Fs = Nothing
Set OraDynaset = Nothing
Set OraDatabase = Nothing
Set OraSession = Nothing
  


ASP による GLOBAL.ASA 利用
  
<OBJECT 
	runat=Server
	scope=Application
	id=OraSession
	progid="OracleInProcServer.XOraSession"
></OBJECT>
<SCRIPT language=VBScript runat=Server> 

' **********************************************************
' アプリケーション開始
' **********************************************************
Sub Application_OnStart

	OraSession.CreateDatabasePool 1,40,200,"LIGHTBOX","STUDY/STUDY", 0

End Sub

' **********************************************************
' アプリケーション終了
' **********************************************************
Sub Application_OnEnd


End Sub

' **********************************************************
' セッション開始
' **********************************************************
Sub Session_OnStart


End Sub

' **********************************************************
' セッション終了
' **********************************************************
Sub Session_OnEnd


End Sub

</SCRIPT>
  










  infoboard   管理者用   
このエントリーをはてなブックマークに追加





フリーフォントWEBサービス
SQLの窓WEBサービス

SQLの窓フリーソフト

素材

一般WEBツールリンク

SQLの窓

フリーソフト

JSライブラリ