[BASP21] HTTPプロトコルでファイルをアップロードする

  サンプルソースコード



  
<HTML>
<BODY>

<%
if Ucase( Request.ServerVariables("REQUEST_METHOD") ) = "POST" then

	Dim nLength,nRet
	Dim ByteArray
	Dim Obj
	Dim FileName

	nLength = Request.TotalBytes
	ByteArray = Request.BinaryRead( nLength )

	Response.Write nLength & " バイトのデータが読み込まれました......<br>"

	Set Obj = Server.CreateObject("basp21")
	nRet = Obj.FormSaveAs( ByteArray, "FileField", Server.MapPath( "baupl.dat" ) )
	Select Case nRet
		Case -1
			Response.Write "渡されたパラメータは、1バイトの配列ではありません<br>"
		Case -2
			Response.Write "フォームの中に名前がありません<br>"
		Case -3
			Response.Write "ファイルを作成できません<br>"
		Case -4
			Response.Write "ファイルの書込みが失敗しました<br>"
		Case Else
			Response.Write nRet & " バイトのファイルを作成しました<br>"
			FileName = Obj.FormFileName( ByteArray, "FileField" )
			Response.Write "読み込まれたファイル名は、" & FileName & "です<br>"
	End Select

else
%>

	<FORM
	 enctype=multipart/form-data
	 action=<% = Request.ServerVariables("SCRIPT_NAME") %>
	 method=POST
	>

	<INPUT
	 type=file 
	 name=FileField
	 size=20
	><br>

	<INPUT type=submit value=アップロード><br>

	</FORM>

<% end if %>

</BODY>
</HTML>

  










  infoboard   管理者用   
このエントリーをはてなブックマークに追加




SQLの窓  天気  IT用語辞典
Yahoo!ニュース  マルチ辞書
PHP マニュアル  Google URL短縮 


フリーフォントWEBサービス
SQLの窓WEBサービス

SQLの窓フリーソフト

素材

一般WEBツールリンク

SQLの窓

フリーソフト

JSライブラリ