VBScriptによるバックアップ

  デバイス一覧



  
' オブジェクト作成
Set objServer = CreateObject("SQLDMO.SQLServer")

' 接続
Call objServer.Connect( "localhost", "sa", "" )

strList = ""
For Each objDev in objServer.BackupDevices
	strList = strList & objDev.Name & " : "
	strList = strList & objDev.PhysicalLocation & vbCrLf
Next

' 切断
Call objServer.DisConnect()

Wscript.Echo strList
  



  デバイス作成



  
Const SQLDMODevice_DiskDump = 2

strTarget = "MyBackup"

' オブジェクト作成
Set objServer = CreateObject("SQLDMO.SQLServer")
Set objBackupDevice = CreateObject("SQLDMO.BackupDevice")
 
' デバイスプロパティをセット
objBackupDevice.Name = strTarget
objBackupDevice.PhysicalLocation = "c:\temp\MyBackup.dat"
objBackupDevice.Type = SQLDMODevice_DiskDump
 
' 接続
Call objServer.Connect( "localhost", "sa", "" )
 
' 既に存在するデバイスを削除
on error resume next
Set objDevice = objServer.BackupDevices.item(strTarget)
if Err.Number = 0 then
	Call objDevice.Remove( )
end if
on error goto 0
 
' 追加
Call objServer.BackupDevices.Add( objBackupDevice )
 
' 切断
Call objServer.DisConnect()
 
' ファイルそのものはバックアップ時に作成されます
  



  バックアップ

  
Const SQLDMOBackup_Database = 0

' オブジェクト作成
Set objServer = CreateObject("SQLDMO.SQLServer")
Set objBackup = CreateObject("SQLDMO.Backup")
 
' バックアッププロパティをセット
objBackup.Action = SQLDMOBackup_Database
objBackup.Database = "lbox"
objBackup.Devices = "MyBackup"
 
' 接続
Call objServer.Connect( "localhost", "sa", "" )
 
' バックアップ
Call objBackup.SQLBackup( objServer )
 
' 切断
Call objServer.DisConnect()
  










  infoboard   管理者用   
このエントリーをはてなブックマークに追加





フリーフォントWEBサービス
SQLの窓WEBサービス

SQLの窓フリーソフト

素材

一般WEBツールリンク

SQLの窓

フリーソフト

JSライブラリ