HTTP Get -- 各キャラクタセットのWebページの読込み ( IXMLHTTPRequest )

  Shift_Jis ページの読み込み



responseText は、euc か utf-8 のページの場合 unicode として変換されますが、Shift_Jis は仕様外の
ようです。ですから、responseBody でいったんバイナリ保存してから、読み込む事になります。

  
Set Stream = CreateObject( "ADODB.Stream" )
Set Fso = CreateObject( "Scripting.FileSystemObject" )

strUrlTarget = "http://hp.vector.co.jp/authors/VA003334/"

Set Http = CreateObject("Msxml2.XMLHTTP.3.0")
Call Http.Open("GET", strUrlTarget, FALSE )	' FALSE は同期処理
Http.Send

Stream.Open
Stream.Type = 1	' バイナリ
Stream.Write Http.responseBody	' Write はバイナリ用
Stream.SaveToFile "Shift_Jis_Page.txt", 2
Stream.Close

Set objHandle = Fso.OpenTextFile( "Shift_Jis_Page.txt", 1 )
For I = 1 to 30
	WScript.Echo objHandle.ReadLine
Next
objHandle.Close
  



  Shift_Jis ページ以外の読み込み



shift_jis 以外では、メモリ上で処理可能です

  
Set Stream = CreateObject( "ADODB.Stream" )

strUrlTarget = "http://euc-jpまたはutf-8ベージのURL"

Set Http = CreateObject("Msxml2.XMLHTTP.3.0")
Call Http.Open("GET", strUrlTarget, FALSE )	' FALSE は同期処理
Http.Send

Stream.Open
Stream.Type = 2	' テキスト
Stream.WriteText Http.responseText	' WriteText はテキスト用

Stream.Position = 0
Stream.LineSeparator = 10	' LF
For I = 1 to 30
	WScript.Echo Stream.ReadText( -2 ) 
Next

Stream.Close
  



  unicode のまま保存

  
Set Stream = CreateObject( "ADODB.Stream" )

strUrlTarget = "http://euc-jpまたはutf-8ベージのURL"

Set Http = CreateObject("Msxml2.XMLHTTP.3.0")
Call Http.Open("GET", strUrlTarget, FALSE )	' FALSE は同期処理
Http.Send

Stream.Open
Stream.Type = 2	' テキスト
Stream.WriteText Http.responseText	' WriteText はテキスト用
Stream.SaveToFile "Save_As_Unicode.txt", 2
Stream.Close
  



  他のキャラクタセットに変えて保存

  
Set Stream = CreateObject( "ADODB.Stream" )

strUrlTarget = "http://euc-jpまたはutf-8ベージのURL"

Set Http = CreateObject("Msxml2.XMLHTTP.3.0")
Call Http.Open("GET", strUrlTarget, FALSE )	' FALSE は同期処理
Http.Send

Stream.Open
Stream.Type = 2	' テキスト

Stream.Charset = "shift_jis"
'Stream.Charset = "euc-jp"
'Stream.Charset = "utf-8"

Stream.WriteText Http.responseText	' WriteText はテキスト用
Stream.SaveToFile "Save_As_Not_Unicode.txt", 2
Stream.Close
  










  infoboard   管理者用   
このエントリーをはてなブックマークに追加




SQLの窓  天気  IT用語辞典
Yahoo!ニュース  マルチ辞書
PHP マニュアル  Google URL短縮 


フリーフォントWEBサービス
SQLの窓WEBサービス

SQLの窓フリーソフト

素材

一般WEBツールリンク

SQLの窓

フリーソフト

JSライブラリ