WMI の ASP での利用

  匿名アクセスを無効にして統合Windows 認証を有効にする



Windows 2000 や XP では、IIS のアプリケーション毎のディレクトリセキュリティで設定します。
( IIS ユーザを Administrators グループに参加させるとその必要はありません )

Microsoft の詳細は こちら です

以下は実行サンプルです

  
<HTML>
<HEAD>
<TITLE>デフォルトゲートウェイとIP アドレスの表示</TITLE>
</HEAD>

<BODY>

<%

ConnectString = "winmgmts:{impersonationLevel=impersonate}!root\cimv2"
Query = "SELECT IPAddress, DefaultIPGateway"
Query = Query & " FROM Win32_NetworkAdapterConfiguration"
Query = Query & " WHERE IPEnabled=TRUE"

On Error Resume Next
Set IPConfigSet = GetObject( ConnectString ).ExecQuery( Query )

if Err <> 0 Then
	if Err.Number = -2147217405 then
		Response.Write "Error 0x80041003: Access Denied: "
		Response.Write "Check permissions and file security for this ASP file."
		Response.Write "<BR>"
	else
		Response.Write "エラー説明: "
		Response.Write Err.Description
		Response.Write "エラー番号: "
		Response.Write Err.Number
		Response.Write "<BR>"
	end if
end if

For each IPConfig in IPConfigSet

	if Not IsNull(IPConfig.IPAddress) then
		For i= LBound(IPConfig.IPAddress) to UBound(IPConfig.IPAddress)
			Response.Write "IP Address: "
			Response.Write IPConfig.IPAddress(i) & "<br>"
		Next
	end if

	if Not IsNull(IPConfig.DefaultIPGateway) then
		For i= LBound(IPConfig.DefaultIPGateway) to _
				UBound(IPConfig.DefaultIPGateway)
			Response.Write "Default IP Gateway: "
			Response.Write IPConfig.DefaultIPGateway(i) & "<br>"
		Next
	end if

Next
Response.Write "<BR>"

if Err <> 0 Then
	Response.Write "エラー説明: "
	Response.Write Err.Description
	Response.Write "エラー番号: "
	Response.Write Err.Number
	Response.Write "<BR>"
end if

%>

</BODY>
</HTML>
  



  Window NT 4.0 の場合



当然 WMI SDK 1.5 (Windows 95/98/NT 4.0) がインストールされている必要がありますが、匿名アクセスや統合Windows 認証は関係無く、以下のレジストリを 1 にする必要があります。

HKEY_LOCAL_MACHINE\Software\Microsoft\WBEM\Scripting\Enable for ASP

これは、WMI 構成マネージャで設定する事もできます。

ASP からWMI サービスへのスクリプトアクセスを許可するもので、全てのASP スクリプトは IIS が実行されているアカウント (通常は NT authority\system) を使用して WMI へアクセスします










  infoboard   管理者用   
このエントリーをはてなブックマークに追加





フリーフォントWEBサービス
SQLの窓WEBサービス

SQLの窓フリーソフト

素材

一般WEBツールリンク

SQLの窓

フリーソフト

JSライブラリ