VBScript : WEBWSH : Wscript で実行された場合は Cscript で実行しなおす

  自分自身を Cscript.exe で呼び出す



共通

Wscript で呼び出してしまうと、Echo 処理するたびにメッセージボックスが表示されてしまうので、
それでは問題の出るようなアプリケーションに使用します。

Cscript で呼び出された場合はなにもせずに終了します。その場合は、最後に PAUSE で停止する
事はありません。Wscript から呼び出された時のみ cmd.exe で呼び直す時に、最後に PAUSE
を付加しています


Crun2

コマンドプロンプトの幅を mode コマンドで変更可能です


注意

エクスプローラからダブルクリックされた場合を想定していますが、元々引数があった場合も引き継い
でいます。
Arguments プロパティ

REM **********************************************************
REM Wscript で実行された場合は Cscript で実行しなおす
REM **********************************************************
Function Crun( )

	if ScriptType <> 1 then
		Exit Function
	end if

	Dim str

	str = WScript.FullName
	str = Right( str, 11 )
	str = Ucase( str )
	if str <> "CSCRIPT.EXE" then
		str = WScript.ScriptFullName
		GetWshShell
		strParam = " "
		For I = 0 to Wscript.Arguments.Count - 1
			if instr(Wscript.Arguments(I), " ") < 1 then
				strParam = strParam & Wscript.Arguments(I) & " "
			else
				strParam = strParam & Dd(Wscript.Arguments(I)) & " "
			end if
		Next
		Call WshShell.Run( "cmd.exe /c cscript.exe " & Dd(str) & strParam & " & pause", 3 )
		WScript.Quit
	end if

End Function
Function Crun2( nCol )

	if ScriptType <> 1 then
		Exit Function
	end if

	Dim str

	str = WScript.FullName
	str = Right( str, 11 )
	str = Ucase( str )
	if str <> "CSCRIPT.EXE" then
		str = WScript.ScriptFullName
		GetWshShell
		strParam = " "
		For I = 0 to Wscript.Arguments.Count - 1
			if instr(Wscript.Arguments(I), " ") < 1 then
				strParam = strParam & Wscript.Arguments(I) & " "
			else
				strParam = strParam & Dd(Wscript.Arguments(I)) & " "
			end if
		Next
		Call WshShell.Run( "cmd.exe /c mode con: cols=" _
			& nCol & " & cscript.exe " & Dd(str) & strParam & " & pause", 3 )
		WScript.Quit
	end if

End function


関連する Microsoft のドキュメント

Run メソッド


依存する Function

ScriptType :【基本関数】 : baseFunction
GetWshShell :【基本関数】 : baseFunction
Ss、Dd :【基本関数】 : baseFunction





  使用方法



webwsh_sample_crun.wsf
<JOB>
<COMMENT>
************************************************************
■ WEBWSH Crun 実行サンプル
************************************************************
</COMMENT>

<COMMENT>
************************************************************
 外部スクリプト定義
************************************************************
</COMMENT>
<SCRIPT language="VBScript" src="http://homepage2.nifty.com/lightbox/laylaClass.vbs"></SCRIPT>

<SCRIPT language=VBScript>
' ***********************************************************
' 処理開始
' ***********************************************************
Call laylaFunctionTarget( "http://homepage2.nifty.com/lightbox/" )
Call laylaLoadFunction( "baseFunction.vbs" )

' ***********************************************************
' Crun
' ***********************************************************
Crun

For I = 0 to 10
	Wscript.Echo "繰り返し処理"
Next

</SCRIPT>
</JOB>



ダウンンロード


ブラウザでダウンロード











  infoboard   管理者用   
このエントリーをはてなブックマークに追加





フリーフォントWEBサービス
SQLの窓WEBサービス

SQLの窓フリーソフト

素材

一般WEBツールリンク

SQLの窓

フリーソフト

JSライブラリ