ソース掲示板




すべてから検索

キーワード   条件 表示 現行ログ 過去ログ トピックス 名前 本文

  メンテナンス 前画面に戻る

対象スレッド 件名: 【+lhaca 用】 WEB WSH インストーラ
名前: lightbox
処理選択
パスワード

件名 【+lhaca 用】 WEB WSH インストーラ
名前 lightbox
コメント
WEB 上にあるファイルをダウンロードしてインストールし、
インストール後の設定もしてしまおうというスクリプトです。

@DIV
1) すでにインストールされている場合はアンインストールする
2) インストールを実行する
3) 設定済の Lhaca.ini を Windows ディレクトリに書き込む
4) Sendto ディレクトリにショートカットを作成する
@END

@HTML
<a style="FONT-SIZE: 12px; COLOR: #0000ff; TEXT-DECORATION: none" href="http://winofsql.jp/wsf/install_lhaca.wsf">ブラウザでダウンロード</a>
@HEND

@DIV
http://park8.wakwak.com/~app/Lhaca/Lhaca124.EXE
@END
@C:red(上記 URL がリンク切れで使用できない場合は、
install_lhaca.wsf をダウンロードしてエディタで該当部分を変更すれば、使用できます。)

  ↓該当部分
@DIV
' ***********************************************************
' lhaca をダウンロードする URL
' ***********************************************************
strDownloadPlace = "http://park8.wakwak.com/~app/Lhaca/Lhaca124.EXE"
@END


@DIV
<JOB>
<COMMENT>
************************************************************
 WEB WSH 実行スケルトン
************************************************************
</COMMENT>

<COMMENT>
************************************************************
 外部スクリプト定義
************************************************************
</COMMENT>
<SCRIPT
	language="VBScript"
	src="http://lightbox.in.coocan.jp/laylaClass.vbs">
</SCRIPT>

<SCRIPT language=VBScript>
' ***********************************************************
' 処理開始
' ***********************************************************
Call laylaFunctionTarget( "http://lightbox.in.coocan.jp/" )
Call laylaLoadFunction( "baseFunction.vbs" )
Call laylaLoadFunction( "wmiReg.vbs" )
Call laylaLoadFunction( "toolFunction.vbs" )

'Crun

' ***********************************************************
' lhaca をダウンロードする URL
' ***********************************************************
strDownloadPlace = "http://park8.wakwak.com/~app/Lhaca/Lhaca124.EXE"


' ***********************************************************
' ダウンロード
' ***********************************************************
ret = HTTPDownload( strDownloadPlace, TempDir & "\Lhaca124.EXE" )
if not ret then
	Wscript.Echo ErrorMessage
	Wscript.Quit
end if

Wscript.Echo strDownloadPlace & " をダウンロードしました"

' ***********************************************************
' アンインストール
' ***********************************************************
strValue = ""
strPath = "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\lhaca"
Call WMIRegGetStringValue( HKEY_LOCAL_MACHINE, strPath, "UninstallString", strValue )

if strValue <> "" then
	ret = GetStringDir( strValue )
	' アンインストール
	RunSync( Dd(ret & "\lhaca.exe") & " /u" )
	Wscript.Echo "lhaca をアンインストールしました"
end if

' ***********************************************************
' インストール
' ***********************************************************
RunSync( Dd(TempDir & "\Lhaca124.EXE") )
Wscript.Echo "lhaca をインストールしました"

' ***********************************************************
' ダウンロードファイルの削除
' ***********************************************************
GetFso
Call Fso.DeleteFile( TempDir & "\Lhaca124.EXE", True )

' ***********************************************************
' Lhaca.ini 出力
' ***********************************************************
TargetPath = WinDir & "\Lhaca.ini"
strText = GetInline( "Lhaca_ini" )
Call PutTextFile( TargetPath, strText )

' ***********************************************************
' ショートカット作成
' ***********************************************************
MsgOk("Sendto ディレクトリにショートカットを作成します")
strValue = ""
strPath = "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\lhaca"
Call WMIRegGetStringValue( HKEY_LOCAL_MACHINE, strPath, "UninstallString", strValue )
ret = GetStringDir( strValue )

Set obj = WshShell.CreateShortcut( SendtoDir & "\+Lhaca.lnk")
obj.TargetPath = Dd(ret & "\lhaca.exe")
obj.WindowStyle = 1
obj.IconLocation = ret & "\lhaca.exe"
obj.Description = "+Lhaca"
obj.WorkingDirectory = ret
obj.Save

Wscript.Echo "処理が終了しました"

</SCRIPT>

<COMMENT>
************************************************************
 Lhaca.ini
************************************************************
</COMMENT>
<RESOURCE id="Lhaca_ini">
<![CDATA[
[OrigAsso]
ZIP=CompressedFolder
ZIPXP=504;0506000000000000000000000000000000000000
CAB=CLSID\{0CD7A5C0-9F37-11CE-AE65-08002B2E1262}
[OrigIcon]
ZIP=%SystemRoot%\system32\zipfldr.dll
CAB=cabview.dll,0
[Option]
MeltDirType=1
CompDirType=2
CompType=0
MeltForAllArc=1
MeltMakeDir=1
MeltOpenDir=1
CompOpenDir=1
MeltOverWrite=1
CompOverWrite=1
AssoLzh=0
AssoZip=0
NoIcon=0
AssoCab=0
AssoTgz=0
AssoArj=0
AssoRar=0
]]]]>
</RESOURCE>

</JOB>
@END