自分で書いた絵をフェードアウト・フェードインしながら表示するブログパーツですが、 手書きブログにあるやつは、表示する画像が最新で限定されているし、 作れるんだから自分で作ってしまおうと思ってやってみました。 現段階では、URL 決め打ちですが、 XMLまたはテキストを読み込んで順次表示やランダム表示を作成する予定です。 package ベース( Main.as )になっているのは、 mx を使用しないほうがswf が極端に小さくなるのでそれで始めたんですが、 結局 Fade を使うので意味無くなりましたが・・・ ひととおり使えるものが出来たら、mx ベースで焼き直しします。 今、オンラインマニュアル見に行ったら、またなんか変わってた・・・ adobe の対開発者スタンスは良く解らん。 ブラウザでダウンロード ↓これです(IFRAME で埋め込んでいます) <IFRAME src="http://winofsql.jp/flex3/as_tool/Main.htm" frameborder="no" scrolling="no" width="160" height="240" ></IFRAME> ソースコードFlex はなんでもかんでも「イベント」です。それを意識してコードを読む 必要があります。今回に関しては、若干タイムラインも意識しないと・・・ URLRequest に関しては、いろいろやってみたんですが どんな URL でも読み込んでしまいます。 これはちょっと ??? なんですが、通常自分のドメインで実行するはずだから まあいいかなと思っていますが、とにかく自分の環境はちょっと特殊なので、 気長に他の環境でもテストしようとは思っています。 手書きブログの画像も直接読めました。 考えるだけ無駄っぽいので、情報だけ。 ↓手書きブログにはこんなのがあります( Opera では見えないですねぇ・・・ ) http://img02.pipa.jp/crossdomain.xml ※ Flex やってると、たまに必要になるクロスドメインの情報です デバッグ表示は、ブラウザの表示部分のフラッシュ以外の部分をクリックして、F12 です。 ( Firebug )
// *********************************************************
// Flex3( mx 無し )
//
// ◎ 画像表示パーツ
// load => onload => time(5秒) => fadeout(0.5秒) => load
// fadein は、1秒なので先に終わる
// 5秒後に fadeout が始まり
// fadeout ではいったんタイマー停止して
// fadeout が終わると loadImages へ
// *********************************************************
package {
import flash.display.*;
import flash.events.*;
import flash.utils.*;
import flash.net.*;
import flash.external.*;
import mx.effects.*;
import mx.events.*;
// 背景色
[SWF(width="160",height="220",backgroundColor="#FFFFFF")]
// 表示用クラス 【Sprite】を継承
public class Main extends Sprite {
[Bindable]
[Embed("mail.png")]
private var imgMail:Class;
private var myTimer:Timer = new Timer(5000);
private var loader:Loader = new Loader();
private var counter:int = 0;
private var fadeIn:Fade;
private var fadeOut:Fade;
// *********************************************************
// コンストラクタ
// *********************************************************
public function Main():void {
ExternalInterface.call("console.log", "start");
stage.scaleMode = StageScaleMode.NO_SCALE;
stage.align = StageAlign.TOP_LEFT;
var myImg:Bitmap = new imgMail();
myImg.x = 0;
myImg.y = 162;
stage.addChild(myImg);
// 読み込みタイマーを登録
myTimer.addEventListener("timer", fadeOutProc );
// フェードイン用
fadeIn = new Fade(loader);
fadeIn.duration = 1000;
fadeIn.alphaFrom = 0;
fadeIn.alphaTo = 1;
// フェードアウト用( フェードアウト終了後、load イベント )
fadeOut = new Fade(loader);
fadeOut.duration = 500;
fadeOut.alphaFrom = 1;
fadeOut.alphaTo = 0;
fadeOut.addEventListener(EffectEvent.EFFECT_END, loadImages);
// 最初のロード
loader.x = 20;
loader.y = 0;
loader.alpha = 0;
stage.addChild(loader);
// 読み込み完了イベントを登録
loader.contentLoaderInfo.addEventListener(Event.COMPLETE, loadComplete);
loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, loadError);
loader.load(
new URLRequest(
"http://lightbox.matrix.jp/timg/1217433566200507.png_S.jpg"
)
);
}
// *********************************************************
// 画像をロードして表示
// *********************************************************
private function fadeOutProc(event:TimerEvent):void {
ExternalInterface.call("console.log", "fadeOutProc");
// タイマー停止
myTimer.stop();
// この処理が完了すると、↓の function が開始される
fadeOut.play();
}
// *********************************************************
// 画像をロードして表示
// *********************************************************
private function loadImages(event:EffectEvent):void {
ExternalInterface.call("console.log", "loadImages");
// ソースコード内での切り替え用カウンタ
counter++;
if ( counter > 4 ) {
counter = 1;
}
ExternalInterface.call("console.log", "load");
// 読み込み
switch( counter ) {
case 1:
loader.load(
new URLRequest(
"http://lightbox.matrix.jp/timg/1225300426141908.png_S.jpg"
)
);
break;
case 2:
loader.load(
new URLRequest(
"http://homepage2.nifty.com/lightbox/timg/1229709460227982.png_S.jpg"
)
);
break;
case 3:
loader.load(
new URLRequest(
"http://lightbox.if.land.to/timg/1224216851694379.png_S.jpg"
)
);
break;
case 4:
loader.load(
new URLRequest(
"http://lightbox.matrix.jp/timg/1217433566200507.png_S.jpg"
)
);
break;
default:
myTimer.start();
break;
}
}
// *********************************************************
// 読み込み完了イベント
// *********************************************************
private function loadComplete(e:Event):void {
ExternalInterface.call("console.log", "loadComplete");
fadeIn.play();
// 5秒後に フェードアウト開始
myTimer.start();
}
// *********************************************************
// 読み込みエラーイベント
// *********************************************************
private function loadError(e:IOErrorEvent):void {
ExternalInterface.call("console.log", "load error");
myTimer.start();
}
}}
|
