特定のサイトを信頼する

  ActiveX を制限無しで使用できるようにする



クライアントで使用可能な Microsoft の ActiveX コントロールや COM コンポーネントを自由に利用
可能にする為には、「信頼済みサイト」に ASP が存在するサイトを登録して「レベルのカスタマイズ」
行なう必要がありますが、以下のスクリプトで設定されます
Microsoft の詳細は こちら です

WMI_IETrust.vbs
  
const HKEY_CURRENT_USER = &H80000001
const NOT_HTTPS = &Hfffffffb

' ********************************************************************
' hpcgi2.nifty.com を信頼する
' ********************************************************************
strDomain = "nifty.com"
strServer = "hpcgi2"

' ********************************************************************
' レジストリクラス
' ********************************************************************
Set obj = GetObject _
	("winmgmts:\\.\root\default:StdRegProv")

' ********************************************************************
' このゾーンのサイトには全てサーバーの確認 (https:) を必要とする
' というチェックを外す
' ********************************************************************
strKeyPath = "Software\Microsoft\Windows\CurrentVersion\" _
	& "Internet Settings\Zones\2"
strValueName = "Flags"
obj.GetDWORDValue HKEY_CURRENT_USER,strKeyPath,strValueName,dwValue
dwValue = dwValue and NOT_HTTPS
obj.SetDWORDValue HKEY_CURRENT_USER,strKeyPath,strValueName,dwValue

' ********************************************************************
' サイトの登録
' ********************************************************************
strKeyPath = "Software\Microsoft\Windows\CurrentVersion\" _
	& "Internet Settings\ZoneMap\Domains\" & strDomain
Return = obj.CreateKey(HKEY_CURRENT_USER, strKeyPath)

if strServer <> "" then
	strKeyPath = "Software\Microsoft\Windows\CurrentVersion\" _
		& "Internet Settings\ZoneMap\Domains\" & strDomain & "\" & strServer
	Return = obj.CreateKey(HKEY_CURRENT_USER, strKeyPath)
end if

' http プロトコルで信頼済みサイト
obj.SetDWORDValue HKEY_CURRENT_USER,strKeyPath,"http",2

' ********************************************************************
' 詳細設定
' ********************************************************************
strKeyPath = "Software\Microsoft\Windows\CurrentVersion\" _
	& "Internet Settings\Zones\2"

' ActiveX コントロールとプラグインの実行
strValueName = "1200"
obj.SetDWORDValue HKEY_CURRENT_USER,strKeyPath,strValueName,0

' スクリプトを実行しても安全だとマークされていない
' ActiveX コントロールの初期化とスクリプトの実行
strValueName = "1201"
obj.SetDWORDValue HKEY_CURRENT_USER,strKeyPath,strValueName,0

' スクリプトを実行しても安全だとマークされている
' ActiveX コントロールのスクリプトの実行
strValueName = "1405"
obj.SetDWORDValue HKEY_CURRENT_USER,strKeyPath,strValueName,0

' 署名済み ActiveX コントロールのダウンロード
strValueName = "1001"
obj.SetDWORDValue HKEY_CURRENT_USER,strKeyPath,strValueName,0

' 未署名の ActiveX コントロールのダウンロード
strValueName = "1004"
obj.SetDWORDValue HKEY_CURRENT_USER,strKeyPath,strValueName,0

' Java アプレットのスクリプト
strValueName = "1402"
obj.SetDWORDValue HKEY_CURRENT_USER,strKeyPath,strValueName,0

' アクティブ スクリプト
strValueName = "1400"
obj.SetDWORDValue HKEY_CURRENT_USER,strKeyPath,strValueName,0

' スクリプトによる貼り付け処理の許可
strValueName = "1407"
obj.SetDWORDValue HKEY_CURRENT_USER,strKeyPath,strValueName,0

' ドメイン間でのデータ ソースのアクセス
strValueName = "1406"
obj.SetDWORDValue HKEY_CURRENT_USER,strKeyPath,strValueName,0
  










  infoboard   管理者用   
このエントリーをはてなブックマークに追加





フリーフォントWEBサービス
SQLの窓WEBサービス

SQLの窓フリーソフト

素材

一般WEBツールリンク

SQLの窓

フリーソフト

JSライブラリ