<OBJECT 
	runat=Server
	scope=Application
	id=OraSession
	progid="OracleInProcServer.XOraSession"
></OBJECT>
<SCRIPT language=VBScript runat=Server> 

' **********************************************************
' アプリケーション開始
' **********************************************************
Sub Application_OnStart

	OraSession.CreateDatabasePool 1,40,200,"LIGHTBOX","STUDY/STUDY", 0

End Sub

' **********************************************************
' アプリケーション終了
' **********************************************************
Sub Application_OnEnd


End Sub

' **********************************************************
' セッション開始
' **********************************************************
Sub Session_OnStart


End Sub

' **********************************************************
' セッション終了
' **********************************************************
Sub Session_OnEnd


End Sub

</SCRIPT>

<SCRIPT language=VBScript runat=Server>

' ******************************************************
' Database オブジェクトの取得
' ******************************************************
Function GetDatabase( )

	Set GetDatabase = OraSession.GetDatabaseFromPool(10)
	GetDatabase.LastServerErrReset

End Function

' ******************************************************
' トランザクションの開始
' ******************************************************
Function BeginTran( OraDatabase )

	On Error Resume Next 
	OraDatabase.Session.BeginTrans
	if OraDatabase.Session.LastServerErr <> 0 then
		OraDatabase.Session.CommitTrans
		OraDatabase.Session.BeginTrans
	end if
	On Error Goto 0

End Function

' ******************************************************
' トランザクションの終了
' ******************************************************
Function CommitTran( OraDatabase )

	OraDatabase.Session.CommitTrans

End Function

' ******************************************************
' RollBack
' ******************************************************
Function RollbackTran( OraDatabase )

	OraDatabase.Session.Rollback

End Function

' ******************************************************
' DB読込み
' 【戻り値】: True(データ有り),False(データ無し)
' ******************************************************
Function OraDBGet( _
	OraDatabase, _
	OraDynaset, _
	SqlQuery _
)

	Set OraDynaset	= OraDatabase.CreateDynaset(SqlQuery,2)
	if OraDynaset.EOF then
		OraDBGet = False
	else
		OraDBGet = True
	end if

End Function

' ******************************************************
' SQL文の実行
' ******************************************************
Public Function OraExecute( OraDatabase, SQLCommand )

	On Error Resume Next 
	OraDatabase.ExecuteSQL( SQLCommand )
	if OraDatabase.LastServerErr <> 0 then
		OraExecute = False
	else
		OraExecute = True
	end if
	On Error Goto 0

End Function

</SCRIPT>